/******************************************************************************
Defined in class *Botpack.TournamentHealth*:
	var() int HealingAmount;
	var() bool bSuperHeal; <- has no effect here anymore
In opposite to parent class the health is not limited to Pawn.Default.Health

Version 0, 29 Oct 2014, SeriousBarbie AT barbies DOT world
Version 1, 26 Jun 2025, SeriousBarbie AT barbies DOT world
* recoded
******************************************************************************/
class SBSuperHealthPack expands HealthPack;

var(TournamentHealth) int CanHealUntil;


auto state Pickup {

	function Touch(actor Other) {
	local Pawn P;
	local int HealthIncrement;

		if (ValidTouch(Other))
		{
			P = Pawn(Other);
			if (P.Health < CanHealUntil)
			{
				HealthIncrement = Min(CanHealUntil, P.Health + HealingAmount) - P.Health;
				if (Level.Game.LocalLog != None) Level.Game.LocalLog.LogPickup(Self, P);
				if (Level.Game.WorldLog != None) Level.Game.WorldLog.LogPickup(Self, P);
				P.Health += HealthIncrement;
				if (PlayerPawn(P) != None)
					PlayerPawn(P).ClientMessage(PickupMessage $ HealthIncrement, 'Pickup');
				PlaySound(PickupSound, , 2.5);
				if (Level.Game.Difficulty > 0)
					Other.MakeNoise(0.1 * Level.Game.Difficulty);
				SetRespawn();
			}
		}
	}
}

defaultproperties {
	CanHealUntil=2000
	HealingAmount=1500
	PickupMessage="You picked up the Super Big Keg O' Health +"
	RespawnTime=300.000000
	MultiSkins(2)=FireTexture'Indus4.RedFire'
}